Workflow – Reading Container Values Using FM and Class

-

Hello Everyone!👋

Reading Workflow Container Values Using FM and Class

If you’ve worked with workflows, you’ve likely encountered situations where you need to access container values within your program.

Most of the time, we use the function module SAP_WAPI_READ_CONTAINER for this.
However, there’s an alternative approach you can also retrieve container values using the class CL_SWF_RUN_WORKITEM_CONTEXT. 

CLASS lcl_workflow_container DEFINITION.
  PUBLIC SECTION.
    METHODS: get_value_using_fm
      IMPORTING iv_wi_id        TYPE sww_wiid
                iv_element_name TYPE swfdname
      EXPORTING ev_value        TYPE any.
    METHODS: get_value_using_method
      IMPORTING iv_wi_id        TYPE sww_wiid
                iv_element_name TYPE swfdname
      EXPORTING ev_value        TYPE any
      RAISING   cx_swf_cnt_container.
ENDCLASS.
CLASS lcl_workflow_container IMPLEMENTATION.
  METHOD get_value_using_fm.
    TYPES: tt_swr_cont TYPE TABLE OF swr_cont WITH DEFAULT KEY.
    DATA(lv_return_code) = VALUE sy-subrc( ).
    DATA(lt_container_values) = VALUE tt_swr_cont( ).
    CALL FUNCTION 'SAP_WAPI_READ_CONTAINER'
      EXPORTING
        workitem_id      = iv_wi_id
      IMPORTING
        return_code      = lv_return_code
      TABLES
        simple_container = lt_container_values.
    IF lv_return_code <> 0.
      RETURN.
    ENDIF.
    ev_value = VALUE #( lt_container_values[ element = iv_element_name ]-value OPTIONAL ).
  ENDMETHOD.
  METHOD get_value_using_method.
    TRY.
        DATA(lo_context) = cl_swf_run_workitem_context=>get_instance( iv_wi_id ).
        DATA(lo_container) = lo_context->if_wapi_workitem_context~get_wf_container( ).
        lo_container->get( EXPORTING name = iv_element_name
        IMPORTING value = ev_value ).
      CATCH cx_swf_cnt_container INTO DATA(container_error).
        RAISE EXCEPTION container_error.
      CATCH cx_root INTO DATA(diaper).
        RAISE EXCEPTION NEW cx_swf_cnt_container( previous = diaper ).
    ENDTRY.
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.
  DATA lv_wi_id TYPE sww_wiid VALUE '453180'.
  DATA lv_element_name TYPE swfdname VALUE '_WF_INITIATOR'.
  DATA(lv_wf_initiator_fm) = VALUE xubname( ).
  DATA(lv_wf_initiator_mehd) = VALUE xubname( ).
  DATA(lo_wf_container) = NEW lcl_workflow_container( ).
  "Get Element value using FM
  lo_wf_container->get_value_using_fm(
    EXPORTING
     iv_wi_id = lv_wi_id "Workitem ID
     iv_element_name = lv_element_name "Element Name
   IMPORTING
     ev_value = lv_wf_initiator_fm "Value
  ).
  "Get Element value using Method
  lo_wf_container->get_value_using_method(
   EXPORTING
      iv_wi_id = lv_wi_id "Workitem ID
      iv_element_name = lv_element_name "Element Name
   IMPORTING
    ev_value = lv_wf_initiator_mehd "Value
  ).

Comments

Post a Comment

Popular posts from this blog

Fiori URL Generation and Navigation Using CL_LSAPI_MANAGER

-
Hello Everyone!👋 Fiori URL Generation and Navigation Using CL_LSAPI_MANAGER CL_LSAPI_MANAGER - This class allows you to easily generate SAP Fiori Launchpad URLs or trigger intent-based navigation. You’ll find it useful when you need to: Launch Fiori apps from the SAP GUI Generate dynamic Fiori URLs using semantic objects, actions, and parameters Share specific Fiori app links via email Navigate directly to transactions, and more DATA(lo_lsapi) = cl_lsapi_manager=>get_instance( ). " Generate URL to launch a Fiori app DATA(lv_flp_app_url) = cl_lsapi_manager=>create_flp_url( object = 'MaintenanceObject' " Semantic Object action = 'listFunctionalLocStructure' " Action system_alias = 'LOCAL' " SM59 Alias for FES parameters = VALUE #( name = 'DY_TPLNR' value = '0001' ) ). " Generate URL to launch a tran...
Read more

RAP - Real Time UI Updates Using Event-Driven Side Effects

-
Hello Everyone! 👋 Real-Time UI Updates in RAP Using Event-Driven Side Effects We've all come across situations where something changes in the backend, and we want those updates to automatically reflect in the UI without manually refreshing the page. In traditional setups, we used ABAP Channels for this but how can we achieve the same in RAP? Here's a simple example: I'm updating the travel status in one class/report, while the app is open in parallel. As soon as the status is updated in the backend, it automatically reflects in the UI no refresh needed! This is made possible through Event-Driven Side Effects . This is useful when: Background jobs update data We want to notify users with messages in real time Multiple users are working on the same data simultaneously Step 1 – Add the event-driven side effects in the BDEF managed with additional save .... .. define behavior for YR_YABS_TRAVEL...
Read more

ABAP - Create CSV Files Easily Using CL_CSV_FACTORY

-
Hello Everyone! 👋 Create CSV Files Easily in ABAP Using CL_CSV_FACTORY In many scenarios, we need to download internal table data in CSV format. Often, the requirements vary for example, using different field separators such as semicolon (;), comma (,). Additionally, we may need to include a header row and format fields like date, time, or timestamp. All of this can be handled very easily using the CL_CSV_FACTORY class. The best part is that this class is also available in the SAP Public Cloud. Step 1 – Select the Data SELECT FROM vbak FIELDS vbeln, vbtyp, erdat INTO TABLE @DATA(lt_test) UP TO 10 ROWS. Step 2 – Create a Simple CSV with Header This example generates a CSV using a semicolon as the delimiter and includes the header row automatically. DATA(lv_xstring_v1) = cl_csv_factory=>new_writer( )->set_delimiter( ';' )->set_write_header( abap_tr...
Read more